群体药动学药效学模型
一、药效学模型简介
明确药物暴露、药效和时间之间的关系。
经验性的药动学药效学模型包括了直接效应模型、效应室模型和翻转模型。机制性模型较经验性模型更为复杂，进一步考虑了药物的作用靶点、与临床终点 事件相关的标志物等因素。
二、常用的药动学药效学模型
直接效应模型
药效学直接效应模型可用来描述大多数药物的药动学和药效学之间的关系。表达式如下：
E_t=E_0+\frac{E_{\max } \cdot C_{\mathrm{p}, t}^\gamma}{E C_{50}^\gamma+C_{\mathrm{p}, t}^\gamma}
其中E0为药效学指标的基线水平,Cpt为t时刻的血药浓度,Et为t时刻的药效学响 应值,γ为Hill系数,决定曲线的形状｡当γ=1时,即为简化的Emax模型｡
药物浓度与效应的关系也可以为线性关系,一般药物浓度远低于EC50,上述EMAX模 型可简化为线性模型
E_t=E_0+\operatorname{SLOPE} \times \mathrm{C}_{\mathrm{p}, t}
上试中slope为斜率
建立直接效应的药动学药效学联合模型相对较为简单,将药动学模型的个体预测浓 度或者个体预测参数(AUC或Cmax)直接代入药效学模型即可｡NONMEM程序中既可以 使用ADVAN模块,也可以采用/$PRED模块实现直接效应模型
1. ADVAN模块
本例中使用了ADVAN2模块构建一房室药动学模型和药效学的直接效应模型｡数 据文件见表81｡数据文件中以指示变量DVID区分药动学和药效学观测值,DVID= 2和DVID=3分别代表血药浓度和药效学指标。
ＡＤＶＡＮ２模块采用的数据文件
$PROBLEM synchronous pd, pkpd_advan, direct Emax
$INPUT ID TIME DV AMT MDV EVID DVID WT
$DATA 8-1.csv IGNORE=#
$SUBROUTINES ADVAN2 TRANS2 ; 1cmt oral
$PK
;--------------pk prameters------------
KA = THETA(1)
CL = THETA(2) * EXP(ETA(1)) * (WT/60)**(THETA(8))
V = THETA(3) * EXP(ETA(2)) * (WT/60)
;---------------pd parameters------------------------
EMAX = THETA(4) * EXP(ETA(3))
EC50 = THETA(5)
EBSL = THETA(6)
HILL = THETA(7)
$ERROR
CP = A(2)/V ; drug concentration of central compartment
EFF = EBSL + EMAX*CP**HILL/(EC50**HILL+CP**HILL) ; drug effect
FLAG = 1
IF(DVID .EQ. 3 ) FLAG = 0
Y = FLAG*(CP*(1+EPS(1))+EPS(2)) + (1-FLAG)*(EFF*(1+EPS(3)))
IPRED = FLAG*CP + (1-FLAG)*EFF
IRES = DV - IPRED
DEL = 0
IF (DV .EQ. 0) DEL = 1
IWRES = (1-DEL) * IRES/(DV + DEL)
$THETA
(0,1) ;KA
(0,0.5) ;CL
(0,10) ;V
(0,100) ;EMAX
(0,12) ;EC50
(0,1) ;EBSL
(0,1) ;Hill
(0,1) ;WT_CL
$OMEGA
(0.1) ; IIV CL
(0.1) ; IIV V
(0.1) ; IIV EMAX
$SIGMA
(0.1) ; EPS1_prop pk
(0.1) ; EPS2_add pk
(0.1) ; EPS3_prop pd
$EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
; Xpose
$TABLE ID TIME DV AMT DVID MDV EVID DVID WT KA CL V EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 CP EFF
PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=run8-1.fit
$TABLE ID TIME DV AMT DVID MDV EVID PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=sdtab8-1
上述文件中,CP为浓度预测值,EFF为药效学预测值｡本例中在/$PRED模块定义了药动学药效学链接的Sigmoid最大效应公式｡
2. PRED模块
- 每个受试者仅有单个观测值
本例考察了峰浓度（Ｃｍａｘ）与心电图的校正ＱＴ间期延长（ΔＱＴｃ）的关系，说明如何用 /$PRED来编码此类模型。数据集中的每条记录都包含了药动学指标（Ｃｍａｘ）和药效学指标 （ΔＱＴｃ）的观测值。如表所示
本例中，每个受试者仅有单个观测值，因此无法区分个体间变异和残差变异，模型估 算的变异为总变异。药效学指标与药动学指标的关系可表示为
\Delta Q T c=a \times C_{\max }+b
其中，ａ表示斜率，ｂ表示截距。ＮＯＮＭＥＭ代码如下：
;; 2. Description: pkpd_pred, linear
$PROBLEM pkpd_pred, linear
$INPUT ID=DROP DQTC=DV CMAX
$DATA 8-2.csv IGNORE=#
$PRED
A = THETA(1) ;slope
B = THETA(2) ;intercepter
EFF = A * CMAX +B ;linear pd
Y = EFF + ETA(1) ;加和型 个体间+个体内总变异
$THETA
(0,0.08) ; slope
(0,0.3) ; intercepter
$OMEGA
(0.1) ; inter-&intra-individual
$EST METHOD=0 MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
$TABLE DV CMAX EFF FILE=run8-2.fit
该模型通过线性回归模型将自变量和DV进行关联｡b和a分别是线性模型的截距 和斜率参数｡EFF是ΔQTc的模型预测值,Y为ΔQTc的观测值,NONMEM将EFF与残差 模型中的Y值相关联｡
- 每个受试者有多个观测值
本例中每个受试者有多个药动学（药物浓度）的观测值及其相对应的药效学观测值，因 此可估算模型参数的个体间变异。药动学和药效学的函数关系为Sigmoid最大效应公式。
在本例中未对药动学模型进行任何假设或估算，仅将药物浓度观测值与药效学进行关 联，使用该方法要求每个药效学观测值对应一个药动学观测值。数据文件格式见表
ＮＯＮＭＥＭ控制文件如下：
;; 2. Description: pkpd_pred, Emax
$PROBLEM synchronous pd, pkpd_pred, Emax
$INPUT ID TIME DV CON
$DATA 8-3.csv IGNORE=#
$PRED
EMAX = THETA(1) * EXP(ETA(1))
EC50 = THETA(2)
EBSL = THETA(3)
HILL = THETA(4) * EXP(ETA(2))
EFF = EBSL + EMAX*(CON**HILL)/(EC50**HILL+CON**HILL)
IPRED = EFF
Y = EFF * (1+EPS(1))
IRES = DV-IPRED
DEL = 0
IF (DV .EQ. 0) DEL = 1
IWRES = (1-DEL) * IRES/(DV + DEL)
$THETA
(0,100) ;EMAX
(0,10) ;EC50
(0,1) ;EBSL
(0,1) ;HILL
$OMEGA
(0.1) ; IIV EMAX
(0.1) ; IIV HILL
$SIGMA
(0.1) ; EPS1_prop
$EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
; Xpose
$TABLE ID TIME DV CON EFF EMAX EC50 EBSL HILL ETA1 ETA2 IPRED PRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=run8-3.fit
$TABLE ID TIME DV PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=sdtab8-3
效应室模型
效应室模型通常可用来描述药物的药动学和药效学之间的延迟现象，且假设药动学 和药效学之间的延迟是由于药物分布到靶组织的过程造成的。该模型假定药物作用的靶 点位于一个效应室或称生物相中，且仅有少量的药物进入效应室，对于药物清 除的影响可忽略不计。图８２为一房室药动学和效应室药效学的模型结构示意图。
图中Ｃp是中央室的血药浓度，效应室的浓度(Ｃe)由下式表示：
\frac{\mathrm{d} C_{\mathrm{e}}}{\mathrm{d} t}=k_{2 \mathrm{e}} \cdot C_{\mathrm{p}}-k_{\mathrm{e} 0} \cdot C_{\mathrm{e}}
若将药效学模型的效应室视为周边室,则可用二房室药动学模型的ADVAN4模块定 义上述过程,数据文件同表81,NONMEM控制文件如下:
$PROBLEM 2cmt pkpd_Effect compartment ADVAN4
$INPUT ID TIME DV AMT MDV EVID DVID WT
$DATA 8-4.csv IGNORE=#
$SUBROUTINES ADVAN4 TRANS4 ; 1cmt oral + effect compartment
$PK
;---------------pk prameters------------
KA = THETA(1)
CL = THETA(2) * EXP(ETA(1)) * (WT/60)**(THETA(9))
V2 = THETA(3) * EXP(ETA(2)) * (WT/60)
;---------------pd parameters------------------------
EMAX = THETA(4) * EXP(ETA(3))
EC50 = THETA(5) * EXP(ETA(4))
EBSL = THETA(6)
HILL = THETA(7) * EXP(ETA(5))
;----------------effect compartment parameters---------
KE0 = THETA(8)
V3 = V2 * 0.001 ; effect volume,set to very small
Q = KE0 * V3
$ERROR
CP = A(2)/V2 ; drug concentration in central compartment
CE = A(3)/V3 ; drug concentration in effect compartment
EFF = EBSL + EMAX*CE**HILL/(EC50**HILL+CE**HILL) ; drug effect
FLAG = 1
IF(DVID .EQ. 3 ) FLAG = 0
Y = FLAG*(CP*(1+EPS(1))+EPS(2)) + (1-FLAG)*(EFF*(1+EPS(3)))
IPRED = FLAG*CP + (1-FLAG)*EFF
IRES = DV - IPRED
DEL = 0
IF (DV .EQ. 0) DEL = 1
IWRES = (1-DEL) * IRES/(DV + DEL)
$THETA
(0,1) ;KA
(0,0.5) ;CL
(0,10) ;V2
(0,100) ;EMAX
(0,10) ;EC50
(0,1) ;EBSL
(0,1) ;Hill
(0,0.03) ;KE0
(0,1) ;WT_CL
$OMEGA
(0.1) ;IIV CL
(0.1) ;IIV V2
(0.1) ;IIV EMAX
(0.1) ;IIV EC50
(0.1) ;IIV HILL
$SIGMA
(0.1) ; EPS1_prop pk
(0.01) ; EPS2_add pk
(0.1) ; EPS3_prop pd
$EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
; Xpose
$TABLE ID TIME DV AMT DVID MDV EVID WT KA KE0 CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 CP CE EFF
PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT NOAPP FILE=run8-4.fit
$TABLE ID TIME DV AMT DVID MDV EVID PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=sdtab8-4
$TABLE ID TIME MDV DVID KA KE0 CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 ONEHEADER NOPRINT FILE=patab8-4
$TABLE ID TIME MDV DVID WT ONEHEADER NOPRINT FILE=cotab8-4
自定义模型
;; 2. Description: pkpd_advan6, Effect compartment
$PROBLEM 2cmt pkpd_Effect compartment
$INPUT ID TIME DV AMT CMT MDV EVID DVID WT
$DATA 8-5.csv IGNORE=#
$SUBROUTINES ADVAN6 TOL=6 ; 1cmt oral + effect compartment
$MODEL
COMP=(DEPO,DEFDOSE)
COMP=(CENTRAL,DEFOBS)
COMP=(EFF)
$PK
;---------------pk prameters------------
KA = THETA(1)
CL = THETA(2) * EXP(ETA(1)) * (WT/60)**(THETA(9))
V2 = THETA(3) * EXP(ETA(2)) * (WT/60)
K20 = CL/V2
;--------------pd prameters------------
EMAX = THETA(4) * EXP(ETA(3))
EC50 = THETA(5) * EXP(ETA(4))
EBSL = THETA(6)
HILL = THETA(7) * EXP(ETA(5))
;----------------effect compartment parameters---------
KE0 = THETA(8)
$DES
DADT(1) = -KA * A(1)
DADT(2) = KA * A(1) - K20 * A(2)
DADT(3) = KE0* (A(2)/V2-A(3)) ; A(3) was defined as drug concentration in effect compartment
$ERROR
CE = A(3) ; drug concentration in effect compartment
CP = A(2)/V2 ; drug concentration in central compartment
EFF = EBSL + EMAX*CE**HILL/(EC50**HILL+CE**HILL) ; drug effect
FLAG = 1
IF(CMT .EQ. 3 ) FLAG = 0
Y = FLAG*(CP*(1+EPS(1))+EPS(2)) + (1-FLAG)*(EFF*(1+EPS(3)))
IPRED = FLAG*CP + (1-FLAG)*EFF
IRES = DV - IPRED
DEL = 0
IF (DV .EQ. 0) DEL = 1
IWRES = (1-DEL) * IRES/(DV + DEL)
$THETA
(0,1) ;KA
(0,0.5) ;CL
(0,10) ;V2
(0,100) ;EMAX
(0,10) ;EC50
(0,1) ;EBSL
(0,1) ;Hill
(0,0.03) ;KE0
(0,1) ;WT_CL
$OMEGA
(0.1) ;IIV CL
(0.1) ;IIV V2
(0.1) ;IIV EMAX
(0.1) ;IIV EC50
(0.1) ;IIV HILL
$SIGMA
(0.1) ; EPS1_prop pk
(0.01) ; EPS2_add pk
(0.1) ; EPS3_prop pd
$EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
; Xpose
$TABLE ID TIME DV AMT CMT MDV EVID DVID WT KA KE0 CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 ETA5 CP CE EFF
PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=run8-5.fit
$TABLE ID TIME DV AMT CMT MDV PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=sdtab8-5
$TABLE ID TIME MDV CMT KA KE0 CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 ETA5 ONEHEADER NOPRINT FILE=patab8-5
$TABLE ID TIME MDV CMT WT ONEHEADER NOPRINT FILE=cotab8-5
翻转模型
;; 2. Description: pkpd_advan6, Turn over
$PROBLEM pkpd Turn over
$INPUT ID TIME DV AMT CMT MDV EVID DVID WT
$DATA 8-6.csv IGNORE=#
$SUBROUTINES ADVAN6 TOL=6 ; 1cmt oral + turn over compartment
$MODEL
COMP=(DEPO,DEFDOSE)
COMP=(CENTRAL,DEFOBS)
COMP=(TURNOVER)
$PK
;--------------pk prameters------------
KA = THETA(1)
CL = THETA(2) * EXP(ETA(1)) * (WT/60)**(THETA(9))
V2 = THETA(3) * EXP(ETA(2)) * (WT/60)
K20 = CL/V2
S2 = V2
;--------------pd prameters------------
EMAX = THETA(4) * EXP(ETA(3))
EC50 = THETA(5) * EXP(ETA(4))
EBSL = THETA(6)
HILL = THETA(7)
;--------------turn over prameters------------
A_0(3) = EBSL
KOUT = THETA(8) * EXP(ETA(5))
KIN = KOUT * EBSL
$DES
CP = A(2)/V2 ; drug concentration in central compartment
EFF = 1 + EMAX*CP**HILL/(EC50**HILL+CP**HILL) ; drug effect
DADT(1) = -KA * A(1)
DADT(2) = KA * A(1) - K20 * A(2)
DADT(3) = KIN* EFF - KOUT * A(3)
$ERROR
IPRED = F
FLAG = 1
IF(CMT .EQ. 3 ) FLAG = 0
Y = FLAG*(F*(1+EPS(1))+EPS(2)) + (1-FLAG)*(F*(1+EPS(3)))
IRES = DV-IPRED
DEL = 0
IF (DV .EQ. 0) DEL = 1
IWRES = (1-DEL) * IRES/(DV + DEL)
$THETA
(0,1) ;KA
(0,0.5) ;CL
(0,10) ;V2
(0,100) ;EMAX
(0,10) ;EC50
(0,1) ;EBSL
(0,1) ;Hill
(0,0.05) ;KOUT
(0,1) ;WT_CL
$OMEGA
(0.1) ;IIV CL
(0.1) ;IIV V2
(0.1) ;IIV EMAX
(0.1) ;IIV EC50
(0.1) ;IIV KOUT
$SIGMA
(0.1) ; EPS1_prop pk
(0.01) ; EPS2_add pk
(0.1) ; EPS3_prop pd
$EST METHOD=1 INTER MAXEVAL=9999 NOABORT SIG=3 PRINT=5
$COV PRINT=E
; Xpose
$TABLE ID TIME DV AMT CMT MDV EVID DVID WT KA KOUT CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 ETA5 CP EFF
PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT NOAPP FILE=run8-6.fit
$TABLE ID TIME DV AMT CMT MDV PRED IPRED RES IRES IWRES CWRES ONEHEADER NOPRINT FILE=sdtab8-6
$TABLE ID TIME MDV CMT KA KOUT CL V2 EMAX EC50 EBSL HILL ETA1 ETA2 ETA3 ETA4 ETA5 ONEHEADER NOPRINT FILE=patab8-6
$TABLE ID TIME MDV CMT WT ONEHEADER NOPRINT FILE=cotab8-6
三、药动学药效学模型的其他考虑
药动学参数的输出
输出cmax和tmax定义
$ABBREVIATED COMRES=2
文章评论